*save_checkpoint

*text_image chap_6.png center Chapter Six
*temp chosearesfirst false
*temp chosearesfirst false
*temp notgame false
*temp hateheroes false
*temp horny false
*temp coolaboutmercy false
*temp dontwanttheron false
*temp theronleads false


You arrive home after another nightmare run, welcomed back by the cries of the damned echoing in the distance. And a fresh poppy poking you in the eye when you cross the gate. 

Morpheus has beat you back. @{(race) How infuriating|Again|How infuriating|Again|How unfortunate|Again|And this time, you didn't trick him into it|Again}. Considering how hard Hermes has been working you lately, it's hardly surprising.

Still, you haven't heard a peep from the herald regarding Leukas and its Lord.

You can't decide if he's being forgetful, or devious. Either way, your increasingly demanding schedule isn't doing your social life any favors. You can't remember the last time you @{(parentsrel) spent time|argued|fraternized} with your parents or @{(Zagreus > 50) berated|teased} Zagreus.

Fates, you've barely had a chance to unpack your recent visit to Olympus.

*page_break And What A Visit

A mortal month has gone by since, and
*if (aresoutcome = 1) or (aresoutcome = 3)
    the memory of your picnic with Ares is enough to make you smile.
    *goto aresletters
*if (aresoutcome = 4) or (aresoutcome = 5)
    the memory of Ares's @{(sexwithares) body tangled with yours|lips on yours} is enough to make you @{(demure > 50) blush|grin}. 
    
    Alas, as delightful as it was to find respite from your responsibilities, respites are only temporary. Even for deities. 
    
    Perhaps especially for deities. 
    
    After all, the world spins only because you turn it.
    *goto aresletters
*else
    you're still not over how much of a bore it ended up being.

    Fates, you're almost glad you've got so much on to make up for it.
    *goto main23

*label aresletters

Your respective duties may have kept you from spending further time together, but you've made up for it in scrolls. 

Iris drops his messages when they deliver souls, and returns yours when they report to Hermes.

[i]It appears I've found yet another hobby to ignite my father's fury; scroll writing! It's far too much fun not to indulge it, however. And I'm far too keen to know how you're faring after your last visit,[/i] Ares had written shortly after you returned from your picnic. [i]I myself haven't been able to stop smiling since you left.[/i]

*if justfriendsares = true
    It has been wonderful to get to know your old friend anew.
    *goto main23
*else
    As for your replies, they've been

    *fake_choice
        #On the flirty side. How could they not be, after all the fun we had?
            *set aresresponse 1
            *set Ares %+5
            He's more than just your old friend and, while it's been fun to get to know him anew, wooing him, and being wooed by him, has been better.
        #On the curious side. Yes, we had fun, but I want us to build a deeper connection.
            *set aresresponse 2
            *set Ares %+10
            And he has been more than happy to oblige, opening up to you as frankly–and sweetly–as he did during your visit.
        #On the cautious side. Having fun is one thing, building a deeper connection is quite another.
            *set aresresponse 3
            *set Ares %-5
            You're not certain where you stand when it comes to your future, and writing back too effusively might send the wrong message.

            Either way, it's been interesting to get to know your old friend anew.
 
*label main23
*page_break

As you near Elyisium, a rainbow plunges into the palace like an iridescent sword.

If Iris has come this late–it was well past dawn when you finished your nightmare run–they must want to talk.

You spot the aide as you near your chambers' wrap-around balcony. They're leaning against a column, feathered wings tucked against their back. Their satchel is brimming with twice as many scrolls as Hermes usually carries, and they clink together when they wave.

"${name}," they greet you. "I was hoping I'd catch you on my way out. Long run, I take it?"

What do you reply?

*fake_choice
    #"Interminable, actually."
    #"That obvious, huh?"
    #"Aren't they all, these days?"
    #"Nothing I can't handle."

They shake their head and smile. "Things have been rather hectic lately."

"The push for worship continues, then?"

They nod, eyes turning a dark, somber blue. "The Giants have accepted Zeus's invitation to feast." 

He must be delighted.

"Here." Iris retrieves @{(aresoutcome) two scrolls from their satchel and hands them over|a scroll from their satchel and hands it over|two scrolls from their satchel and hands them over|two scrolls from their satchel and hands them over|two scrolls from their satchel and hands them over}.

Then they hesitate, eyes shifting to a bright amber before they speak again. "I'm glad you brought the Lord of Leukas's concerns before Hermes, by the way. It is our duty to speak on behalf of mortals as much as it is our duty to act on behalf of the gods."

They are kind words. And within them, you sense an opportunity. 

To assert your position on the Council's current leadership, perhaps. Or, to dig around for information on what Hermes is really up to.

*choice
    #I tell them how confident I am in their leadership skills.
        "The Messengers ought to be led by someone like you," you tell them. "Fair and just, even when it's difficult or unpleasant."

        *if demure < 50
            *set respect %+15
            *set peoplepleaser %+5
            *set olympusinfluence %+10
            They give you a wide, genuine smile. "I'm honored you think so."

            "I mean it," you add. "These are uncertain times. We need certain leaders." 

            They stare out to the mist-shrouded mountains looming in the distance. "Uncertain times indeed. I understand the Giants are great threat, and securing worship is a matter of protection. But I worry about the cost. For mortals. For us."

            Hermes, on the other hand, seems more worried about what he stands to gain, rather than what everyone else stands to lose.
            *goto main25
        *else
            *set respect %-10
            *set pantheonplayer %-10
            *set olympusinfluence %-15
            They shift uncomfortably. "Things have been especially challenging for Hermes lately. Zeus is pressuring everyone to secure more worship to deal with the Giants. I know it's hard at the moment, but that doesn't mean Hermes isn't being fair and just, considering the circumstances."

            There's a sharpness to their voice you haven't heard before. It shames you into silence.
            *goto main25
    #I probe them for information I could use against Hermes.
        @{(pissedoffhermes) He certainly seemed keen on your ruin at the meeting. It won't hurt to secure some collateral|You never know when you might need some collateral}. Something you could use to help or hinder him, should his leadership come into question.

        "I know how hard it has been for Hermes lately," you begin. "What with Zeus demanding so much worship. You must be worried about him. I certainly am." 

        Their eyes turn a turbulent grey. 

        "I am worried," they admit. "Zeus is convinced the Giants will attack. And Hermes…Well, you know Hermes. He's not so concerned about the cost of securing worship at this rate. He seems much more focused on the profit."

        "And does this profit concern Leukas?"

        *if cunning > 50
            *set respect %+5
            *set maverickgoddess %+10
            *set underworldinfluence %+10
            *set hermeslying true
            "I can't say for sure. Either way, I don't like the way it is being handled. Or isn't being handled, rather."

            "So he hasn't spoken to Zeus yet? About Leukas, I mean."

            "Not yet."
            *goto main25
        *else
            *set respect %-15
            *set maverickgoddess %-10
            They stiffen, as though realizing they've spoken out of turn. "Apologies, I shouldn't have said that."

            "It's okay."
            
            They grip the strap of their satchel. "No. It was inappropriate."

            "Has he spoken to Zeus, then? About Leukas?" You venture, attempting to salvage your ploy. But it's in vain.

            "I'm not privy to their conversations, ${name}." 
            
            There's a sharpness to their voice you haven't heard before. It's obvious you won't get anything but more bitterness from them.
            *goto main25
    #I assure them it's a duty I also take very seriously.
        "You're right," you tell them.
        *if leadership > 50
            *set respect %+15
            *set maverickgoddess %+10
            *set olympusinfluence %+10
            "Not only is it our duty, but it is also a calling. One greater than we are, and one we must always answer, no matter how difficult or unpleasant the circumstances."

            Iris looks at you with something you can only describe as reverence. 
            
            "Spoken like a true leader," they beam.
            
            The compliment fills you with warmth.
            *goto main25
        *else
            *set respect %-15
            *set olympusinfluence %-10
            But Iris jumps in before you can add anything else.

            "Not only is it our duty, but it is also a calling. One greater than we are, and one we must always answer, no matter how difficult or unpleasant the circumstances."

            You blink away your surprise. They took the words right out of your mouth.

            "You're right. Again."
            *goto main25
    #I praise Hermes for agreeing to bring my concerns to Zeus.
        "That is why I'm so pleased Hermes is talking to Zeus," you tell them. "I know he has a lot on his plate. As do we, I suppose."

        *if dutiful > 50
            *set respect %+20
            *set pantheonplayer %+10
            Iris nods. "How right you are. Things have been especially challenging for him lately, what with Zeus convinced the Giants will attack." 
            
            They pause, as though weighing their next words carefully. "I do worry about the cost of securing worship at this rate. For mortals. For us."

            You squeeze their shoulder. "If Zeus demands it, then we shall pay it."

            They pat your fingers gently. "How right you are again."
            *goto main25
        *else
            *set respect %-15
            *set olympusinfluence %-10
            Perhaps you're still in nightmare mode. Or perhaps you're just a contrarian at heart. But something about your tone sounds off. Almost mocking.

            Iris jumps to Hermes's defence upon hearing it. "Yes. Though Hermes in particular is under a lot of pressure, what with Zeus convinced the Giants will attack. Securing worship is of utmost importance."

            "Of course," you agree, lowering your chin.

            Iris cocks an eyebrow at you, as though trying to determine whether you're being genuine. You make yourself smile in an attempt to reassure them.
            
            Whether it works or not is unclear.
            *goto main25

*label main25
*page_break

"Right, I had best get going," the aide announces, spreading their wings. A nacre sheen drips from the tips of their feathers, forming the beginning of a rainbow. "Take care of yourself, ${name}."

With that, they take off, leaving behind another multi-colored trail.

*if (aresoutcome != 2)
    You glance down at the scrolls in your hand. You recognize the handwriting on both at once. One is from Hermes, no doubt containing your instructions for tonight. The other is from Ares. 
    
    Which do you read first?

    *choice
        #Hermes's scroll. My duties must come first.
            *set leadership %+5
            It is the price of divinity, after all.
            *goto hermesscroll
        #Ares's scroll. My duties can wait.
            *set dutiful %-5
            *set Ares %+5
            *set chosearesfirst true
            It's not like you're neglecting them.

            Delaying them a little won't hurt.
            *goto aresscroll
*else
    *set chosearesfirst true
    You glance down at the scroll in your hand. You recognize the handwriting. It's from Hermes, no doubt containing your instructions for tonight.

    What fresh torment does he have in store, you wonder?
    *goto hermesscroll

*label hermesscroll
*page_break Read Hermes's Scroll

The herald's scroll is predictably to the point. 

No greeting, no pleasantries, not even a signature.

[i]Focus your nightmares on Leukas. Make its Lord increase the people's nightly libations by whatever means necessary[/i].

That's unexpected. @{(hermeslying) You know the order hasn't come from Zeus. So why has he sent it?|Does this mean he has spoken to Zeus?} And why nightly libations specifically?

Frowning, you chuck the scroll onto your desk.

*if chosearesfirst
    *goto main26
*else
    *goto aresscroll

*label aresscroll
*page_break Read Ares's Scroll

[i]${name},[/i] Ares's scroll begins.

[i]@{(hobby) How's the weaving coming along?|How's the training coming along?|Have you been practicing the aulos?|Have you been playing any good games, lately?}. I have just returned from delivering the Giants' invitation to my father's great feast. I must thank you for your suggestion.[/i]

What did you suggest he do in your last scroll?

*fake_choice
    #That he wear something revealing to distract the Giant Queen.
        *set demure %-5
        @{(aresoutcome > 4) It would work on you, wouldn't it?|Why not? It might work on you.}

        [i]Alas, I decided against it. Showing up in only my loincloth would have certainly made an impression, but I am not sure it is the kind my father was talking about when he chose to send me there.[/i]

        That is because, unlike you, Zeus lacks vision.
    #That he perform an interpretative dance to impress the Giant Queen.
        *set charm %+5
        [i]Alas, I am a dreadful dancer, and would have likely elicited a declaration of war on the basis of my performance. Perhaps you can teach me some moves at the feast?[/i]

        @{(aresoutcome > 4) Oh, he knows how to move alright|Why not?}
    #That he bring ambrosia cake to bribe the Giant Queen.
        *set cunning %+5
        [i]She was skeptical at first–apparently, they prefer pies–but came around once she tasted it. Was it enough to convince her not to bring war to the feast? I guess we will have to wait and see.[/i]

        You wish you could've seen the Giant Queen's reaction when he handed over the wrapped up golden dome. Imagining it alone makes you smirk.

Extremely unhelpful suggestions aside, it had surprised you, when he'd revealed he was being sent to the Giant's territory. Hermes or Iris are meant to deliver such messages. Though you suppose sending the god of war to do so is a message in itself.

Or a punishment.

You return your attention to the scroll.

[i]I'm to travel to my uncle Poseidon's palace deep in the ocean next to help co-ordinate the sea's attack strategy. If you have any suggestions for how I might handle such a task, I will sadly not receive them until I return, as I doubt Iris will be able to squeeze in a trip to the ocean's deepest, darkest depths to deliver them.[/i]

[i]I will be back before the feast, of course. Perhaps then would be a good time to visit you in the Underworld, even if I won't be able to stay long? Being a little woozy is a small price to pay to experience your realm, and finally witness its misty beauty with my own two eyes.[/i]

[i]Yours,[/i]

[i]Ares[/i]

[i]P.S. The hatchlings are doing well. Growing stronger everyday, even venturing into the stream to hunt, though I did have to mimic how to do it first.[/i]

Smiling, you tuck the scroll into one of your desk drawers, alongside the others. 

Unlike Hermes's, these you get to keep. Cherish, even, if you so wish.

*if chosearesfirst
    *goto hermesscroll
*else
    *goto main26

*label main26
*page_break

Beyond your balcony, Iris's double rainbow curves into the lavender sky.

@{(leaningtowards) If Ares walked onto it, he'd soon be woozy and weakened. But he'd marvel at the view all the same, you're certain.|What would Theron think of a sky that is forever bruised and glinting with souls instead of stars?|Can Morpheus see the colors glinting from his home in the mountains? Does he hate the sight of them, like he hates everything else?}

You eye @{(hobby) your tapestry, stretched out on the loom propped against a wall|the gymnasium, calling to you from the other side of the acropolis|your aulos, calling to you from its case|the petteia board with Zagreus and Averna's ongoing game still unfolding across it}.

Averna emerges from the shadows before you get the chance to @{(hobby) tend to it|grab your gear|reach for it|study it, as though you summoned her}.

"I ought to be on the Messengers' Council myself, what with all this back and forth," she offers by way of greeting.

What do you reply?

*fake_choice
    #"Charming as ever."
    #"Hello to you too."
    #"Perhaps if you stopped whining."
    #"Perhaps I'll put in a good word."

If her hands weren't full she'd probably wave you off. 

Alas, a tray balances on her long, bony fingers, and your breakfast awaits atop it.

*if sexwithares = true
    A pitcher of nectar, a plate of ambrosia-laced fruit, some cheese, and the thing you asked her to get for you as soon as you returned from Olympus; Circe's brew, named so after the witch-goddess who grows the herb required to make it. 
    
    It has a [i]powerful[/i] smell. Bitter and earthy, but also overripe. Then again, it's a powerful brew. It has to be, to prevent pregnancy in deities.
    *goto main27
*else
    A pitcher of nectar, a plate of ambrosia-laced fruit, and some cheese.
    *goto main27

*label main27
*page_break

The lampad places the tray on the table and it barely makes a sound, as though she's transferred her ability to be sneaky to it.

She picks at the cheese while you @{(sexwithares) reach for the brew. You take a sip and grimace. All week, you've been drinking it, and you're still not used to the foul taste|down the nectar}.

*if sexwithares
    "Wash it down," Averna says when you finish it, handing you the nectar.

    You down it, eager to get rid of the bitterness caking your tongue.

    "As awful as it is, I'm grateful you secured it for me," you tell her, even though she only did so because she lost your gown to the bottom of the ocean.

    She shrugs and gets to her feet. "Some things shouldn't be left to the Fates."

    "Off already?"

    "Afraid so," she sighs. "You know how it is, duty calls."

    By duty, she means your mother, of course.
    *goto preleaving
*else
    "Since when do you do food deliveries?" you wonder.

    "Since your mother asked me to. She knows how hard you've been working and wants to make sure you're fuelling up properly." Her expression doesn't quite soften, but there's a lessening of its usual sharpness. "I believe she misses you."

    @{(parentsrel) You miss her too|You roll your eyes. Perhaps she should've come herself, then|How comforting}.
    *goto preleaving

*label preleaving
*page_break

"What, pray tell, is the Queen up to these days?"

Averna cocks an eyebrow at you. "What she's always up to. Preparing for spring, passing judgement on souls, and fretting over her children's wellbeing."

@{(sexwithares) You glance at the cup of Circe's brew. Empty, but still foul-smelling. "I take it she isn't fretting over that?"|She takes the last piece of cheese and gets to her feet.}

@{(sexwithares) "I was off duty when I got it," she assures you with a wink.|"Off already?"}

@{(sexwithares) She|"Duty calls." She} casts a longing glance at the board of petteia, then she's gone as quickly as she arrived, slipping into the shadows before the door to your chamber closes.

*page_break 

By the time you travel to Hellas, the sun has sunk below the horizon. But its warmth lingers, already thick with the promise of spring. Soon, your mother will leave the Underworld to stay with her mother. Together, they'll make flowers bloom and fruit ripen. Chase away the cold and ready the fields for harvest. Wake wildlife from their slumber and call the birds back from faraway lands. 

Back-breaking work, even for a deity. Hence why it requires two.

Hovering above the mortal realm, you call your Epiali forth. They gather around you like a dark cloud, waiting for their orders. Which are to….

*fake_choice
    #Do as Hermes asks.
        *set dutiful %+5
    #Be merciful.
        *set ruthless %-5
    #Be fearsome.
        *set charm %-5
    #Be sneaky.
        *set stealth %+5
    #Be fair.
        *set leadership %+5

They @{(epiali) hiss|squeak|caw|meow|blink} in agreement and you follow after them, becoming one with their @{(epiali) serpentine|furry|feathered|furry|furry} shadows until you reach Leukas.

Where the agora is abuzz with music and merriment, and where people crowd the cobbled streets and the torch-lit taverns. 

Where the air smells of wine and sacrificial smoke.
    
Your Epiali retreat to the Halfrealm, where they'll wait for sleep to claim the island.

Judging by the frequent sound of laughter, you imagine they'll be waiting a while.

*page_break Find Theron

Shrouded in night, you fly to Theron's home, landing on the balcony with a soft thud. 

But the Lord of Leukas is nowhere to be found. 

The wooden @{(epiali) snake|bat|raven|cat|spider} he was working on the night he first asked for your help is on the table. He's finished it, in the nights since. You study @{(epiali) each delicate scale, the forked tongue poking out of its open mouth, the sharp fangs that frame it|its delicate wings, its furry ears, its sharp fangs|each delicate feather, the sharp beak, the curved talons|its sharp eyes, pretty whiskers, furry ears|its curving legs, its furry body, its many eyes}. It's beautiful. 

And not at all why you came here. 

You peel your gaze away from the carving and aim it at the revel. Your best bet is to join it. But a goddess at a mortal feast sticks out like the moon among the stars. You must don a disguise. That way…

*fake_choice
    #It will be easier to talk to Theron.
        *set Theron %+5
        *set leukasnight 1
    #I can play spy for the night.
        *set stealth %+5
        *set leukasnight 2
    #I can play at being mortal for the night.
        *set dutiful %-5
        *set leukasnight 3
            
Determined, you slip into Theron's chambers. 

The dark doesn't stop you from making out what's in them. The simple jug and bowl he must use to pour his nightly libations gleaming by the empty hearth. The bed, with a curved wooden frame you suspect he might have built himself, just like the chest at the foot of it. The tapestries hanging on the walls, of waves and vines and trees.

And the standing mirror in the corner, with hippocampi etched all along its frame.

Your reflection regards you closely. Godhood makes your hair shine, your skin glow, your clothes ripple gracefully with each movement.

You had better remedy that.

Who do you transform into?

*fake_choice
    #A servant girl so I can blend in.
        *set disguise 1
        *set stealth %+5
    #An aulos girl so I can show off.
        *set disguise 2
        *set demure %-5
    #A party girl so I can have a little fun.
        *set disguise 3
        *set charm %+5

Drawing on the well of power within you, you begin dulling the edge of your divinity.
*if (nightmaresuccess = true) and (skimmedworship = true)
    It's a growing well, befitting of a goddess who knows how to extract worship to her advantage.

    But who is still young.
    *goto disguise
*elseif (nightmaresuccess = true) and (skimmedworship = false)
    It's a modest well, befitting of a goddess who is nicely worshiped, but who is also young. 
    *goto disguise
*else
    It's a lacking well. Your worship has been hit-and-miss of late, and it shows.
    *goto disguise

*label disguise
*page_break

The likes of Zeus and your parents could hold a new form for all eternity, if they so wished. The worship they have amassed is so great, it doesn't fit in a well. It spans oceans.

You, on the other hand, won't get away with wearing this face long before it begins wearing on you.

You shake your head and admire your handiwork in the mirror.

A mortal girl stares back at you from its depths. She has a hint of your features.
*if disguise = 1
    But she's more mousy-looking and plainly dressed, so as not to draw too much attention.
    *goto disguise1
*elseif disguise = 2
    And though there's a brazen air about her–the sure way she grips her aulos, the charming curve of her smile–it's far from divine.
    *goto disguise1
*else
    Pretty, but not in the way gods are. 
    
    In a way that's easy to behold directly.
    *goto disguise1

*label disguise1

And of course, not a @{(flightstyle) wing|wavering shadow|winged sandal} in sight.

*page_break Join The Feast

Satisfied, you leave Theron's chambers behind. Through the door, for a change.

Once outside, you're greeted by a balmy breeze. The agora is at the bottom of the hill, and the streets get busier and rowdier the closer to it you amble. 

Despite the party atmosphere, the people seem more weary than winsome. Too many are too thin, and tiredness clings to their faces like paint.

Still, many smile at you as you scurry by, catching bits of their conversations.

[i]"They are heroes. It's a privilege to host them."[/i]

[i]"What they paid for the ship will barely cover the amount of food they're eating, let alone the amount of wine they're chugging."[/i]

[i]"Zeus values hospitality above all else. By honoring the heroes, we honor him."[/i]

[i]"Heroes? Thieves is more like it!"[/i]

*if leaningtowards = 2
    So the heroes have their ship, and yet they linger in Theron's city.

    You frown, unsettled by the discovery.
    *goto main29
*else
    The heroes are still here, then. 
    
    Sounds as though they've outstayed their welcome.
    *goto main29

*label main29

Yes, Zeus demands mortals, like gods, be gracious hosts. 

But he also demands they be gracious guests.

*page_break

You resume your search for Theron with renewed determination.

With no patron deity to speak of, a leader of unremarkable lineage, and an agora smaller than your father's courtyard, Leukas feels more like a village than a city. 

But there's an undeniable charm to it. Everything is dry stone–the streets, the walls, the many steps. Greenery pokes its head between it, some of it manicured, some of it wild. And the sea stretches beyond the nearby harbor, filling it with the smell of brine and the sound of the waves shaping the shore.

You've seen the agora in Theron's nightmares, but it's different to actually walk through it. It feels more lived-in, yes, but also more alive. 

The fountain at its heart is a little cracked, but it does a good job of holding the musicians perched on the edge of the basin. The mosaic floor is well-worn, but you can still glimpse the twisting patterns of its pebbles. The flanking olive trees are gnarled with age, but their branches reach wide, and votive offerings have been placed around the base of their trunks.

You glance around. Theron ought to be here somewhere.

Where do you look for him?

*choice
    #By the votive offerings. I can study the Leukans' worship habits while I'm at it.
        *set offerings true
        *set cunning %+5
        You wander closer to the olive trees.
        
        There are still people leaving offerings at their roots. Flowers, statuettes, bird feathers, horse hair braids. Most are for Zeus and Poseidon–the sky and the sea keep the island and its people fed, after all–but you do notice a fair few dedicated to Hypnos.

        *if nightmaresuccess
            And some for you, too. @{(flower) Crocuses|Daffodils|Quince flowers|Nightshades}, and even some figurines. @{(flightstyle) Winged|Shadow-shrouded|Wing-footed} and @{(bodytype) slender-limbed|full-bodied|well-built}.
            *goto petteia
        *else
            You do spy the odd @{(flower) crocus|daffodil|quince flower|nightshade}, too. No @{(flightstyle) winged|shadow-shrouded|wing-footed} and @{(bodytype) slender-limbed|full-bodied|well-built} figurines though. 
    
            You haven't made [i]that[/i] much of an impact.
            *goto petteia
    #By the fountain. There's no reason not to enjoy the music while I search.
        *set charm %+5
        You join the throng of folk dancing, twirling around the agora as you search for their Lord.
        *goto petteia
    #In the taverns lining the agora's edges. I could use a glass of wine.
        *set demure %-5
        One is much busier than the others. A large crowd has gathered around its entrance, cheering and sighing loud enough to pique your curiosity. 

        Someone hands you a glass of wine as you approach. It isn't sweet and delicate like nectar, but it's delicious all the same. Rich and layered and a little earthy, much like the landscape it hails from.

        It's gone by the time you carve a path through the crowd.
        
        @{(disguise) The people pay you no mind as you weave through them, reaching the front easily|You flash your aulos, nodding at the girls playing inside the tavern, and squeeze through to the front|A pretty smile here, a gentle shoulder touch there, and you reach the front}.
        *goto main30

*label petteia
*page_break

A loud cheer draws your eye to a crowd gathered around one of the taverns nearby.

Leukans begin flocking to it. Even the musicians join them, too curious to keep up with their tune. 

Before you can react, an old lady grabs your hand. 

"C'mon girl, he needs our prayers if he's going to beat her tonight," she croaks.

She carves a path to the front, dragging you with her.

*label main30
*page_break

Theron presides over one end of a petteia board laid out at the center of a long wooden table, surrounded by heroes. 

You've terrorized enough of them to know that's what they are. The ichor in their blood is thin, but it does give them a god-like aura. It's strongest in Theron's petteia opponent–a dark-haired woman with shrewd eyes and plenty of presence. 

She wears deep-red robes and an amulet in the shape of two torches hangs from her neck. You recognize the symbol. It's worn by priestess of Hecate.

No wonder she has the upper hand; your aunt's worshippers are a clever bunch.

*page_break

"While we are keen to resume our quest for glory," the woman says, moving a piece forward, "we must await for favorable omens before we set sail. We do not wish to risk the ship you so generously repaired for us."

Theron's pleasant demeanor doesn't waver. He's wearing his laurel crown tonight, and a fine @{(leaningtowards) chiton|chiton you can't imagine has ever seen the shipyard|chiton}.

"You are wise to be cautious, though I myself cannot think of a more favorable omen than this wind. But I am no seer, of course," he says, smiling at her before he returns his attention to the game.

But there's nothing he can do.

His opponent has all but won. He's got one piece left, and hers will surround it on her next turn.

*page_break

"We will be out of your hair as soon as the gods give us their blessing," the young hero beside the woman says. 

Their leader, judging by the eager way the others nod at his words.

The woman chooses that moment to claim her victory, earning gasps from the people and cheers from the heroes.

Theron looks far from disgruntled. No, he's all humility and charm as he praises her.

"You make a fierce opponent, Medea of Colchis."  

Medea of Colchis. 

You've heard of her alright. Granddaughter of the sun god Helios, and as adept with magical herbs as her aunt Circe.

Medea grins at the leader. He takes her hand in his and kisses it.

"Perhaps too fierce," she laments. "When it comes to petteia, I have yet to meet my match. It brings me great sadness, for I long for a proper challenge."

She scans the crowd, as though expecting a challenge to materialize among the gathered mortals. Then her eyes snag on you.

*page_break

"You," she says, waving at you to join them. "Come play, won't you?"

Theron stiffens beside her. You meet his gaze. For the first time since you laid eyes on him, that steely composure of his wobbles. Whether because he recognizes you, or doesn't recognize the mortal you've become, you can't say. 

"She's just @{(disguise) some servant girl|an aulos girl|some village girl}. Surely you do not believe the likes of [i]her[/i] could best you?" the leader huffs.

But Medea isn't deterred. 

"I did not believe the likes of [i]you[/i] could win over my heart. Perhaps she'll prove me wrong too." With that, she beckons you closer.

You take a step forward.

*fake_choice
    #Someone should knock these heroes down a peg.
        *set hateheroes true
    #I, too, appreciate the kind of challenge she longs for.
    #@{(disguise) And bite back a sigh. You're supposed to be blending in|Forget the aulos. This is how I'll show off|This is exactly the type of fun I was after}.
    *if hobby < 4
        #I would rather not play but refusing could blow my cover.
            *set notgame true
 
*if leukasnight = 3
    Besides, petteia on a balmy evening in a cosy tavern would certainly make your night playing mortal a memorable one.
    *goto main32
*else
    *goto main32

*label main32

"Jason," she says, nodding at the leader before addressing the others. "Boys. Make some room for the girl. Go on, sit."

The heroes do as Medea asks. Theron shuffles to the edge of his bench, leaving enough room for you to perch beside him.

Medea clears her pieces from the board and tosses you the ones she took from Theron. 

"Shall we begin?"

*page_break Ready, Set, Go

Theron was right. She's a fierce opponent indeed. Clever and merciless from the moment you place the first piece on the board.

You can feel the heroes' contempt, the Leukans holding their breaths, their Lord watching your every move. 

And Medea, holding your feet to the fire at every turn. 

But you have a strategy of your own.

*choice
    #To fight fire with fire, stopping only when she burns.
        @{(notgame) You didn't want to play, but now that you are, you might as well go all in|Why not go all in? A worthy opponent is what Medea craves, and you're more than happy to oblige her}.

        Unsurprisingly, it doesn't take long for things to get heated. The air becomes heavy, almost charged. It feels less like a game and more like a battle, by the time you're nearing its end. 
                
        Medea remains ruthless through and through, risking her own pieces to claim yours, charging ahead with an intense, almost frenzied focus.

        *if ruthless > 60
            *set beatmedea true
            *set peoplepleaser %+10
            But she's no match for you.
            *goto won
        *else
            *set peoplepleaser %-15
            And it pays off. 
            
            You fight hard–and dirty–but, in the end, it isn't enough.
            *goto lost
    #To lure her into a false sense of security before I strike.
        You make yourself appear as meek as possible. @{(disguise) The hapless servant girl, scared and out of her depth|The free-spirited aulos girl, too enamored by music to bother with mind games|The ditzy party girl, here for drinking games, not mind ones}. 

        "Am I allowed to do this?" you ask early on, moving a piece the wrong way on purpose, and causing Theron to snort into his wine cup.

        But the heroes' leader falls for your trap, and proceeds to over-explain every maneuver that follows.

        *if cunning > 60
            *set beatmedea true
            *set maverickgoddess %+10
            As unbearable as the sound of his voice is, it works in your favor. 
            
            For all her intense, almost frenzied focus, Medea gets cocky–and doesn't even realize she's losing until it's too late.
            *goto won
        *else
            *set peoplepleaser %-15
            But Medea ignores his idle prattling and your little performance. Ruthless through and through. Risking her own pieces to claim yours. Charging ahead with an intense, almost frenzied focus.
            *goto lost
    #To command both the game and the agora with boldness and grace.
        You settle in and hold your ground. @{(notgame) You didn't want to do this, but now that you must, you're determined not to let Medea's intense, almost frenzied focus rattle you|Determination flows through you; you will not allow yourself to be rattled by Medea's intense, almost frenzied focus}.

        It's a close game, and the further into it you get, the quieter the agora grows.

        *if leadership > 60
            *set beatmedea true
            *set worship %+10
            But you stand firm and keep your cool. 

            Soon, you notice the mortals are looking at you instead of at the board. Whispering encouragements, nodding eagerly whenever you make a good move.

            And you feel it. A stir within you, a splash in the well of your power. 

            Worship.
            *goto won
        *else
            *set peoplepleaser %-15
            And though you stand firm and keep your cool, it isn't enough. 

            Medea is too good. Soon, the people are whispering encouragements, nodding eagerly whenever she makes a smart move. Which happens to be every move she makes.

            And though they want the heroes gone, though they are deprived of sleep and worried about their depleted stores, she commands their attention too deftly for them to care so long as they get to bathe in her glory.

            As though she is a Queen. Or a goddess.
            *goto lost

*label won
*page_break

When you take her last piece, a roar ripples through the crowd. And a shriek tears from Medea's throat.

*achieve defeatmedea

For a moment, you fear she might attack you. The heroes tense, and their leader–Jason–looks at her with a mixture of horror and disgust.

"Looks as though the gods have answered your prayers," Theron says. It sounds like a warning.

His words make Medea snap out of whatever dark–and undoubtedly violent–thoughts were plaguing her. 

"My apologies." She blinks, shaking her head. "I have a bad habit of letting my anger get the better of me. Our generous host here is right. You fought well and your victory is more than deserved."

*fake_choice
    #"Thank you."
    #"As did you."
    #"No need to apologize."
    #"So it is."

She nods gratefully before excusing herself. The crowd stop celebrating on your behalf long enough to let her through. 

Then the music and giddiness resumes.
*goto main33

*label lost
*page_break

When she takes your last piece, a roar ripples through the crowd.

"You almost had me there," Medea admits. She looks shaken, as though the mere thought of defeat repulses her. 

What would she have done, you wonder, had she lost?

"The gods certainly granted me my wish this night. I have been properly challenged, if not quite found my match."

How do you respond?

*fake_choice
    #"I fear what might become of your match once you find it."
        "As do I," she sighs. For a moment, sorrow clouds her face.
    #"It has been a pleasure to spar, Medea of Colchis."
        "A pleasure indeed," she agrees.
    #"The gods have been very generous with you indeed."
        She bows her head in agreement.

Then the heroes are showering her with praise and she's being whisked away to the bar. 

The leader–Jason–follows begrudingly, making a big show of rolling his eyes.

It only makes the jealousy he's trying to hide more obvious.
*goto main33

*label main33
*page_break

Theron gently bumps your shoulder.

"Nice @{(disguise) rags|aulos|gown}," he teases.

There's a playful glint in his eyes, and you get the distinct impression he's flirting.

You're overcome by

*choice
    #A wave of desire. I want him, and I don't care if I shouldn't.
        *set Theron %+15
        *set theronfeels 1
        *set horny true
        *goto wanttheron
    #A pang of longing. I want him, even though I can't have him.
        *set Theron %+10
        *set theronfeels 2
        *set horny true
        *goto wanttheron
    #A spark of curiosity. Do I want him?
        *set Theron %+5
        *set theronfeels 3
        He [i]is[/i] handsome. And charismatic. And those eyes of his do have a way of drawing you in.

        @{(sexwithares) But he is mortal. Not to mention your recent tryst with Ares|But he is mortal}….

        And so are you, at least for tonight.
        *goto main35
    #A shimmer of friendship. I want us to get along.
        *set theronfeels 4
        *set theronoutcome 1
        *set justfriendstheron true
        He is a good ruler. Perhaps, once you settle this business with Hermes, he could become a good friend, too.

        As good a friend as a mortal can be, to a goddess.

        Though right now, you're not meant to be a goddess at all.
        *goto main35
    *if (leaningtowards = 1) or (leaningtowards = 3)
        #A big load of nothing.
            *set Theron %-15
            *set theronfeels 5
            *set theronoutcome 2
            Yes, he's handsome. And charismatic.

            But you don't see him as anything other than the mortal Hermes is hellbent on terrorizing. 

            That reminds you. You're meant to be a @{(disguise) meek servant girl|ditzy aulos girl|oblivious party girl}, not some musing goddess.
            *goto main35

*label wanttheron

His life is already forfeit, while yours will stretch on and on and on. Not to mention the doom that always seems to follow @{(aresoutcome > 3) mortals. And your recent visit to Olympus|mortals}.

Still, it's hard not to let those dark eyes of his draw you in.

Hard to remember you're meant to be a @{(disguise) meek servant girl|ditzy aulos girl|oblivious party girl}, not some wistful goddess.

*label main35
*page_break Get Your Act Together

"My Lord," you stammer, lowering your gaze. "It is an honor to sit at your table."

"There's no need for that, Goddess." His tone is low, his grin conspiratorial. "I have broken bread with everyone here. Besides, nobody calls me Lord. Other than my general, but she does so exclusively to mock me."

@{(leukasnight) So much for playing mortal. Though you suppose you did want to talk to him|So much for playing spy|So much for playing mortal}. "What gave it away?"

"You have been haunting my dreams long enough for me to know you regardless of the face you wear," he answers.

*if theronfeels != 5
    @{(horny) Fates help you|How discerning}.

    "Your dreams or your nightmares?"

    His smile widens. "Both."

    @{(thoughtof) You eye him gingerly|You eye him gingerly|You suppose you knew that already}.

    *fake_choice
        #"Do you resent me for it?"
            The words seem to surprise him. 
        
            "Why would I resent you for doing the Fates' bidding? I don't resent the waves for lapping at the shore or the trees for bearing fruit."
        #"Do you loathe me for it?"
            The words seem to shock him. He frowns, shaking his head.

            "Why would I loathe you for doing the Fates' bidding? I don't loathe the waves for lapping at the shore or the trees for bearing fruit."
        #"Do you wish it weren't so?"
            *set wishing true
            "I'm a practical man. I try not to waste time wishing for things that can never be." He pauses, fixing his eyes on yours. "Most of the time."
        #"Do you like being haunted, then?"
            "Depends on who's doing the haunting."

    "Besides," he adds, "while I do find your nightmares utterly terrifying, I'm also grateful for them. They have helped me better serve my people. I'm more cautious because of them, but also more aware of my own mind's pitfalls. It's far too easy, as a leader, to let your emotions cloud your judgement. Facing my fears at night means they are less likely to impact my decisions during the day. At least not without me knowing."

    @{(horny) Fates help you|How discerning} indeed.

    @{(nightmares) "Finally, a mortal who appreciates the power of fear."|"It is rare to find a mortal who appreciates the power of fear."|"Such is the way of the Fates."|"Such is the power of fear. Though I wish it didn't come with so much pain and suffering."|"Only a mortal could find such wisdom in being afraid."}
    
    He smiles, rubbing the scar on his throat.
    *goto theronscar
*else
    @{(justfriendstheron) You smile politely|You merely blink}.

    His expression grows sheepish. He blinks it away, rubbing the scar on his throat.
    *goto theronscar

*label theronscar

*fake_choice
    *if theronfeels != 5
        #"Are you also grateful for that?" I ask.
            "In some ways."
    #"That looks like it hurt," I wager.
    #"Does it bring you comfort, feeling it like that?" I wonder.
        Your father seldom reaches for his.

        "It does," Theron says.
    #"You don't fear how you go that," I state.
        You would know, by now.

        "I ought to."

He traces the pink line with his finger.

"The previous Lord of Leukas was…a complicated man. He was chosen to lead our people when I was a boy. Back then, we had a big raider problem and he was the strongest and cleverest among us. And the most ruthless. He did deal with the raiders, but I suppose it scarred him, doing what he had to do to keep our island safe."

He pauses, glancing at the shore.

"He grew paranoid about threats and too fond of drink, which only made his paranoia worse. The older I got, the more he seemed to think the biggest threat, to the island and to himself, was me."

A ludicrous notion. "Why would he think such a thing?"

"I guess he could see that he might be asked to step down soon. That I might be the one to take his place."

"So he resorted to violence?"

He returns his gaze to you. "I don't think he meant to. He was far too drunk, and I had approached him about a new design for the shipyard that would allow us to build more ships. I should've known @{(leaningtowards) better. I'm good at fixing things, but I'm even better at fixating on them. Sometimes, I'm so busy looking for ways to make what could be, be, that I forget what is|better|better. I'm good at fixing things, but I'm even better at fixating on them. Sometimes, I'm so busy looking for ways to make what could be, be, that I forget what is}."

*page_break Unbelievable

"A man attempts to slit your throat and you blame yourself?" you ask.

He shrugs. "I wouldn't go so far as to call it that. He took a clumsy swing at me with a shard of glass."

A shard of glass. That's all it took, for mortal skin to be forever marked.

What had Morpheus called Odysseus? A blood-thirsty brute who thinks himself clever when, in truth, he is merely cruel. A definition that certainly applies to the previous Lord of Leukas.

"What was his punishment?" you ask, hoping for

*fake_choice
    #Death. 
        *set ruthless %+10
    #Exile.
        *set diplomacy %+10
    #Prison.
        *set charm %-10
    #Mercy.
        *set ruthless %-10
        *set coolaboutmercy true

"He was stripped of his title and accepted help to manage his drunkenness."

"How merciful of you," you @{(coolaboutmercy) observe|hiss}.

Theron smiles.

"He even apologized, and lived out his days looking after the old temple on the cliff. He passed a few springs ago. I haven't got round to finding a replacement yet."

Then he straightens, growing serious all of a sudden.

*page_break

@{(theronfeels < 5) "Speaking of temples|"I must ask}. What news of Olympus? Of my people's plight?"

You consider your answer. @{(hermeslying) The truth is, you don't have one. The fact that Hermes is lying is hardly news|Though the truth is, you don't have one}.

*if hermeslying
    *choice
        #Still. Theron deserves to know about it.
            *set toldtheron true
            *set Theron %+5
            *goto main36
        #And thus, not worth upsetting him over just yet.
            *goto main36
        #And thus, best kept to yourself for the time being.
            *set Theron %-5
            *goto main36
*else
    *goto main36

*label main36

"All I know is that Hermes wishes for me to continue terrorizing your people," @{(toldtheron) you say. "And that he hasn't brought my concerns to Zeus yet."|you say.}

"I see."

He clenches his fists, frustration creasing his brow.

*page_break

Then the music by the fountain shifts, and something loosens in Theron's face. 

The meandering tune speeds into a lively one, woven with singing and clapping and laughter. Even your Epiali @{(epiali) twist|bop|flap|bob|bop} along, tucked into the agora's darkest pockets.

The Lord of Leukas gets to his feet and offers you his calloused hand.

"I am aware you did not come here to feast, let alone dance. But since you [i]are[/i] here…."

*choice
    *if theronfeels < 4
        #I take his hand. I would love nothing more than to dance with him.
            *set dancedwiththeron true
            *set Theron %+10
            *goto dancetheron
    #I take his hand. This is as good as a night off, why not enjoy it?
        *set dancedwiththeron true
        *set Theron %+5
        *goto dancetheron
    *if (theronfeels > 1) or (theronfeels < 4)
        #I hesitate. As tempted as I am, I don't know if it's wise.
            "I really shouldn't," you tell him.

            But it must sound half-hearted, for he keeps his hand where it is.

            "C'mon," he insists.

            *choice
                #Who am I kidding? I'd love to dance.
                    *set Theron %+10
                    *set dancedwiththeron true
                    *goto dancetheron
                #I take his hand. It's just one dance.
                    *set Theron %+5
                    *set dancedwiththeron true
                    *goto dancetheron
                #I shake my head. I can't.
                    *set Theron %-5
                    *goto satback
    *if theronfeels > 3
        #I take his hand. Just because I don't fancy him doesn't mean I can't dance with him.
            *set dancedwiththeron true
            *set diplomacy %+5
            *goto dancetheron
    #I reject his offer. I would rather stay here and soak up the atmosphere.
        *set Theron %-5
        *goto satback
    *if theronfeels = 5
        #I reject his offer. I don't fancy dancing, especially not with him.
            *set Theron %-15
            *goto satback

*label dancetheron

Smiling, he leads you to the heart of the agora.

You've never seen your father dance but, when Zeus does it, the deities around him stop having fun and start trying to impress him. The Leukans don't bat an eye when Theron joins them, welcoming him into their looping circle as they would anyone else; without a fuss.

You breeze through the steps, letting the beat and Theron guide you. He's good at it, both the dancing and the guiding. Smooth and steadfast.

*choice
    *if theronfeels < 4
        #I press closer to him.
            *set Theron %+5
            His feet don't falter, but his face does. The mirth in it vanishes, and his eyes lock on yours, pulling you in as much as the arm he tightens around your waist.
                
            For a moment, he's all you can make sense of. 
            
            Everything else fades. Your @{(horny) guilt|doubts}, the people, even the agora itself. Gone like mist swept away by wind. 
            
            Leaving behind only you and Theron and the music.
            *goto main37
    *if theronfeels > 3
        #I make sure not to press too close.
            *set diplomacy %+5
            You don't want him getting the wrong idea.
            
            Though it becomes clear rather quickly that you don't have to worry about that. 
            
            Theron maintains a respectful distance the whole time, closing it only when the dance demands it, and never overstepping when it doesn't.
            *goto main37
    #I take in our surroundings.
        *set cunning %+5
        Theron spins you around, all finesse and mirth. 

        But you watch the flushed faces that surround you.

        The song seems to have lured everyone to the heart of the agora, as though there's somethign special about it. You can still sense an undercurrent of fatigue, but it's tinged with relief. 
        *goto main37
    #I lose myself in the moment.
        *set fitness %+5
        Your thoughts fade like mist in wind. There is nothing in your mind but music, movement and mirth.

        You sway and you spin and you skip. The tune builds and builds and builds.

        It's freeing as flying, and almost as fun.
        *goto main37

*label satback

He shrugs. "Suit yourself."

You've never seen your father dance but, when Zeus does it, the deities around him stop having fun and start trying to impress him. The Leukans don't bat an eye when Theron joins them, welcoming him into their looping circle as they would anyone else; without a fuss.

*choice
    #I watch him dance.
        *set Theron %+5
        He's a good dancer, smooth and steadfast. 
        
        And not once does his charm slip, not even when one of the girls he twirls around steps on his toes. 

        *if leaningtowards = 2
            You caught a glimpse of the man that lies beneath the beguiling Lord's façade when you last saw him at the shipyard. @{(lefttheron) Not a crack, exactly. A splinter|A small crack, barely bigger than a splinter, when the dying sunlight touched his face and he closed his eyes to enjoy it}. 

            What would it take for him to truly come undone?
            *goto main37
        *else
            What would it take to crack that perfect façade? To catch a glimpse of the man beneath the beguiling Lord?
            *goto main37
    #I watch the people around me.
        *set leadership %+5
        Most of them flood to the agora. Not because of Theron, but because there seems to be something special about this tune.

        They sway and skip and spin. Their faces are flushed, the torches around them flickering to the tune of their leaping breaths. And though you can still sense the undercurrent of fatigue, it's tinged with relief.
        *goto main37
    #I watch the heroes inside the tavern.
        *set cunning %+5
        Medea laughs among them, @{(beatmedea) looking a lot more at ease than last time you saw her|still looking extremely pleased with herself}.

        They all seem enthralled by her. All save for Jason.
        
        His arm is slung around her shoulders, but his eyes never remain on her for long.
        *goto main37

*label main37
*page_break

Then the music stops.

You join the applause that ensues, @{(dancedwiththeron) pretending to be as winded as the Leukans|mimicking the Leukans around you}.

The aulos girls bow before retreating, leaving the people to yawn and shoot pointed glances at @{(dancedwiththeron) the heroes drinking inside the tavern. You notice Medea among them, looking much more at ease than she did last time you saw her|the heroes}. 

Medea is the only one who notices their stares.

"You heard the song, boys," she says, setting down her wine cup. "Party's over."

"It's early still," one of the heroes grumbles.

"Exactly! We have only been fed fish, and not enough of it at that," another adds. "Surely there is meat to be had too."

*if dancedwiththeron
    Beside you, Theron sighs. 

    "I'll take horrifying nightmares over soothing heroes' egos any day," he whispers before excusing himself.
    *goto main38
*else
    Theron is by their side before they get the chance to complain further.
    *goto main38

*label main38
*page_break

The people begin to retire. Your Epiali stir in their hiding spots, readying to strike. 

"Having a good time, goddess?" Medea asks, @{(dancedwiththeron) emerging from behind the fountain|dropping on the bench beside you}.

If she weren't a priestess of Hecate, you might have been offended. 

But your aunt is a demanding patroness, one who wouldn't tolerate a follower who can't see past a simple disguise.

"I simply wanted to extend my thanks," Medea adds. "It is not often deities actually show up, when they grant their blessing. We are thankful for yours, and will leave come dawn."

Your blessing, huh?

*choice
    #I seize the opportunity to steer her and the heroes away from Leukas.
        Yes, she saw past your disguise. But that doesn't mean she'll also question your authority.
        
        "I like to ensure those I am granting my blessing to are worthy of it," you say.

        *if leadership > 60
            *set peoplepleaser %+15
            *set worship %+10
            *set happymedea true
            Your voice doesn't waver, and neither does your gaze.

            It works. She lowers her chin in what you're certain is a rare show of deference

            "A wise move."
            *goto main39
        *else
            *set peoplepleaser %-15
            It comes out more arrogant than you intended. And far less convincing.

            She frowns and toys with her amulet. 
            
            Not exactly the deferent response you were after. 
            
            Far from it, in fact.
            *goto main39
    #I seize the opportunity to squeeze her and the heroes for some worship.
        Yes, she saw past your disguise. But that doesn't mean she'll also question your authority.
        
        "I am glad to hear it, and look forward to seeing how you will honor me in exchange."

        *if cunning > 60
            *set worship %+15
            *set maverickgoddess %+10
            *set happymedea true
            Understanding flickers across her eyes.

            "Of course," she says, lowering her chin. "We will ensure the proper rites are observed in your name."
            *goto main39
        *else
            *set peoplepleaser %-15
            *set maverickgoddess %-10
            Her eyes narrow, as though she can see the trick in your words the way you can see your Epiali skulking in the shadows.

            "Of course."

            But it's more platitude than promise.
            *goto main39
    #I come clean. It's not right to send them on their way on false pretenses.
        "I have not granted you my blessing," you tell her. "That is not why I came here."

        *if ruthless < 60
            *set worship %+10
            *set peoplepleaser %+5
            *set happymedea true
            Her eyes dart towards the tavern, where Theron is refusing another drink, much to his guests' disappointment.

            "I see," she says. "Well, I appreciate the honesty, and will make sure it is duly rewarded."
            *goto main39
        *else
            *set worship %-10
            You have the feeling she's sifting through the words, looking for a trick.
        
            "I see," is all she says. 

            Her lack of gratitude chafes at you. So this is what being kind gets you. 

            A sweet load of nothing. No wonder you don't do it very often.
            *goto main39

*label main39
*page_break

She stares out to the empty agora. Only a few stragglers remain, putting out torches and candles, muttering to themselves about Hypnos's good will.

"Truth be told, we were planning on leaving soon regardless," she admits, nodding at the heroes. "To them, the promise of glory is a lure stronger than any siren song. And they follow it gladly, even if it will lead to their doom. Perhaps because of it. There is nothing more glorious than being immortalized by the poets. And there's nothing the poets love more than doom."

What do you respond?

*fake_choice
    #"I take it you have no interest in being immortalized?"
    #"I take it you are not so glad to follow glory into doom?"
    #"I take it you are not that into poetry?"
    #"I take it you would rather stay here in Leukas?"

She laughs. It's a @{(happymedea) surprisingly merry sound|bitter sound, laced with grief and misery}.

"I have sacrificed too much for this journey not to see it through to the end. Even though oracles have assured me it won't be a happy one. Quite the opposite, in fact."

She toys with her pendant. 

*if (nightmares = 1) or (nightmares = 2)    
    You understand where she's coming from. 
    
    You too, have found purpose in the path set out for you at birth by the Fates, even if it isn't always the easiest one to tread.
    *goto main40
*elseif nightmares = 3
    You feel a current of understanding between you. 
    
    She isn't talking about surrendering to the Fates but, rather, acknowledging their power.
    *goto main40
*else
    You recognize the look in her face. It's a look you've borne many times yourself. 
    
    The look of someone for whom fate is a burden they wish they could shed.
    *goto main40

*label main40

Still, her next words are not what you expect.

"Besides, I am an optimist at heart. Fate is a thread, not a noose. Just because doom has been woven into it doesn't mean it can't be woven out. And it will make a beautiful tapestry either way."

For someone who is so dismissive of poets, she sounds a lot like one.

*page_break

You're interrupted by Theron, who approaches the @{(dancedwiththeron) fountain|table} with a huge grin plastered across his face.

"Apologies for the intrusion," he says cheerfully. "Medea, I believe your companions are eager to rest up before we meet in the harbor at sunrise."

@{(dancedwiththeron) She bows at him, then at you|She gets to her feet and bows}.

"I best join them, then." 

She pauses, 
*if theronfeels < 4
    eyes darting between you and Theron.
    *goto goodbye
*else
    aiming a pointed look at you.
    *goto goodbye

*label goodbye

"Think on it," she mouths, mimicking weaving with her fingers.

Then she's gone. Off to wrangle the rowdy heroes to their beds. 

Leaving you alone with the beaming Lord of Leukas.

*page_break

"I owe you my gratitude. If you had not come this evening, the heroes would still be here tomorrow," he says earnestly.

@{(hateheroes) "They had no business eating you out of house and home like that."|"They're a fun bunch, albeit a little lacking in self-awareness,"} you say, letting your disguise drop. 

Holding it in place was beginning to feel like effort, and you have a sneaky suspicion you'll need all your strength tonight. 

@{(theronfeels) Theron's grin widens when|Theron's grin widens when|Theron's grin widens when|Theron watches as|Theron watches quietly as} @{(flightstyle) your wings burst from your back, making you levitate slightly|shadows drift from your skin, forming a halo of dread around you|wings sprout from your sandals, making you levitate slightly}.

Fates, it feels good.

"I had better take my leave too." 

A courtesy, of course. Sleep is Hypnos's domain. You must wait until it has taken hold before taking care of yours.

@{(dancedwiththeron) You eye the stars, readying to take off|You leap from the bench, readying to take off} for a little while.

*if theronfeels < 4
    "Or you could stay."

    Theron's words make you still. Is he propositioning you? The thought alone makes you

    *choice
        *if theronfeels < 3
            #Giddy; I know it's a bad idea, but I can't seem to remember why.
                *set Theron %+15
                "And do what?"

                He closes the distance between you.
                *goto intotheron
        *if theronfeels < 4
            #Hesitate; I know it's a bad idea, but I'm oh so tempted by it.
                *set Theron %+5
                He must see it in your face, for it emboldens him to close the distance between you, making it even harder for you to think straight. 
                *goto intotheron
        *if theronfeels = 3
            #Hesitate; I still don't know how I feel, but I'll hear him out.
                "And do what?"

                He closes the distance between you.
                *goto intotheron
        #Certain; I want him, @{(horny) and I don't care if it's a bad idea|beyond shadow of a doubt, even if it's a bad idea}.
                *set Theron %+10
                "And do what?"

                He closes the distance between you.
                *goto intotheron
        *if theronfeels = 3
            #Certain; I am only interested in forming a strictly platonic alliance.
                *set justfriendstheron true
                *set dontwanttheron true
                *set theronoutcome 1
                *set Theron %-10
                Whatever curiosity you might have felt is gone.
                *goto rejectedtheron
*else
    "I will see you soon," he says neutrally.
    *goto rejectedtheron2

*label intotheron

"I know we both have duties to tend to. But what if we were to put them aside?" He looks down at you with such intensity, such hope. "We can resume them before dawn. I'll submit to them as gladly as I always do. But until then, let us pretend they don't exist. Let us pretend you came here to feast and dance. Let us enjoy the rest of the night, together."

Moonlight glints on the scar on his neck, the depths of his eyes.

[i]Fate is a thread, not a noose.[/i]

Medea's words come to you unbidden.

*if (aresoutcome = 4) or (aresoutcome = 5)
    What of Ares, though? You are by no means exclusive. Still….
    *goto intotheron1
*else
    *goto intotheron1

*label intotheron1
*page_break

Then Theron is leaning in to kiss you.

*choice
    #To Tartarus with it all. I kiss him back, hard.
        *gosub_scene subroutines theronkiss
        *goto theronkiss2
    #And I'm going to let him. One kiss won't hurt, right?
        *gosub_scene subroutines theronkiss
        *goto theronkiss2
    #I step away. I can't let us cross this line.
        *set Theron %-5
        *set theronoutcome 3
        *goto postkiss

*label theronkiss2

*choice
    #One kiss isn't enough. I want all of him.
        *set sexwiththeron true
        *set Theron %+15
        When he peels away, his breathing is hard and ragged and his eyes are dark with desire that mirrors your own.
        *goto pretheronsex
    #One kiss isn't enough. I'll indulge in a few.
        *set Theron %+10
        You bury your fingers in his curls, kissing him as hard and as much as he can bear.

        Which, it turns out, is a lot.

        When he finally peels away, his breathing is hard and ragged and his eyes are dark with desire. 

        *choice
            #And I know kissing alone won't cut it. I want the rest of him too.
                *set sexwiththeron true
                *goto pretheronsex
            #And I know we have to stop, before desire consumes us both.
                *set theronoutcome 4
                *goto postkiss
    #This kiss is all I will allow myself tonight.
        *set theronoutcome 4
        *set Theron %+5
        *goto postkiss

*label pretheronsex

"I heard something about us enjoying the rest of the night together," you practically pur.

He laughs, cupping your face. "I do seem to recall mentioning that, yes."

His lips brush yours, but he pulls back before you lose yourself to them again.

"We had better get to it, then," he adds.

*page_break Return To His Place

By the time you reach his moonlit chambers, you're close to breathless yourself, though you can't tell if it's from climbing the hill so fast or sheer anticipation.  

Then he's kissing you against the wall, and it doesn't matter.

You can feel how hard he is against your hip. You dig your fingers into his shoulders and arch your back, desperate to let him know you want him just as bad. 

His crown clatters to the ground as his hands work their way under your @{(style) chitoniskos|chiton|peplos}, palms rough against your skin.

Your shoulder pins come loose, leaving your breasts exposed. He makes a choked sound and shifts his mouth towards them. You catch sight of yourself in the nearby mirror. @{(flightstyle) Your wings are splayed out like petals|Your shadow is a dark frame|The wings of your sandals flutter against your ankles}, your gown is all rumpled around your waist, and your @{(hair) hair is|curls are|braids are|hair–your headscarf has long fallen to the floor–is} all bunched up from pressing @{(hair) it|them|them|it} into the wall.

"I believe it's my turn to do the tormenting," he breahtes into the crook of your neck.

*choice
    #I want to watch him torment me.
        *set theronleads true
        *set dutiful %+5
        "It is only fair," you agree. "But I want to see you do it."
        *goto theronforeplay
    #I want him to watch while he torments me.
        *set demure %+5
        *set theronleads true
        "Only if you can see what your torment does to me."

        He follows the direction of your gaze and his lips quirk up. "Deal."

        He shucks off his chiton, giving you a glimpse of what lies beneath-the planes and grooves of his toned body, the dark hair that criss-crosses his torso, the collection of scars scattered across his skin–before sliding behind you so that you're both facing the mirror. 
        
        @{(flightstyle) You point your wings downwards and he loops his arms beneath them, hauling|He loops his arms beneath yours and hauls|He loops his arms beneath yours and hauls} you towards him.
        
        His cock presses into your lower back as he shoves the skirt of your gown aside and reaches a hand between your thighs. The other, he uses to

        *fake_choice
            #Bracket my throat.
                A strong grip that has you gasping as much as his fingers.
            #Cup my breast.
                He grins as he teases you with his fingers.
            #Rip my @{(style) chitoniskos|chiton|peplos} off.
                *set pcnaked true
                "That's better," he says, clearly enjoying the unobstructed view of his fingers teasing and taunting you.

        He drags them up and down slowly, at first. Even when you twist against them. Even when you beg.

        "It is meant to be a torment, is it not?" he teases. 
        
        But his voice is hoarse enough that you know it is torment for him too. Still, he continues drawing out each bit of friction. 
        
        When he finally slides his fingers inside you, you can't help but cry out, digging your nails into his forearm.
        
        His mouth charts the shape of your shoulder, but his eyes are anchored on your reflection. Watching as you come undone in his grip.

        But it isn't enough. You need more. You need [i]him[/i].

        He must feel it, because he lets go of you long enough to nudge your entrance with his cock. You bend over slightly, gripping the mirror's pretty frame.
        *goto sextheron
    #I want him to watch while I torment him.
        *set ruthless %+5
        "I don't think so," you say, catching his wrists.
        *goto theronforeplay  

*label theronforeplay

He follows the direction of your gaze and his lips quirk up. @{(theronleads) "Fair isn't what I'm planning on."|"If you insist."}

@{(theronleads) He leads you to the bed|He lets you lead him towards the bed}. His chiton is gone by the time you reach it. @{(theronleads) You|You allow yourself to} admire the planes and grooves of his toned body, the dark hair that criss-crosses his torso, the collection of scars scattered accross his skin. 

Not for @{(theronleads) as long as you'd like though–he's a mortal on a mission|long, though–you're a goddess on a mission}.

@{(theronleads) He sits|You have him sit} on the edge of the bed, facing the mirror. Then @{(theronleads) he pulls you onto his lap|you kneel behind him and reach around his waist, wrapping your fingers around his cock}.

*if (flightstyle = 1) and (theronleads = true)
    Your wings are flush against his chest. You point them downwards so that you can anchor your gaze on his reflection in the mirror. He loops his arms beneath them and grabs the skirt of your gown.
    *goto theronforeplay1
*elseif (flightstyle > 1) and (theronleads = true)
    Your back is flush against his chest. You anchor your gaze on his reflection as he loops his arms beneath yours and grabs the skirt of your gown.
    *goto theronforeplay1
*else
    He inhales sharply, eyes anchored on your reflection as you move your hand up and down his length.

    Slowly, lazily, delighting in the weight of his back between your thighs, the frantic rise and fall of his chest, the feel of him against your palm.
    *goto theronforeplay2

*label theronforeplay1

He shoves it out of the way and parts your thighs. 

He brings a hand between them. His fingers move up and down, slow and teasing as he cups your breast with his free hand.

*label theronforeplay2
*page_break

@{(theronleads) "Theron," you practically beg|"Goddess," he practically begs}.

@{(theronleads) He nips the soft skin behind your ear|You nip the soft skin behind his ear}. "It is meant to be a torment, is it not?"

*fake_choice
    #@{(theronleads) He takes pity on you and speeds up|I take pity on him and speed up}.
        @{(theronleads) The friction draws a string of gasps from your parted lips. You dig your nails into his forearms, twisting in his grip. Then he slips his fingers inside you|It draws a string of gasps from his parted lips, You move faster, pumping him until he has to bite them to keep from crying out}.
    #@{(theronleads) He keeps that|I keep my} tortuous pace.
        It's torment alright. 

        And the fact @{(theronleads) you can see him|he can see you} deliver it only makes it sweeter.
        
        @{(theronleads) You watch him taunt and tease, drawing out every bit of friction. By the time he slips his fingers inside you, you're a whimpering mess|You taunt and tease, drawing out every pump}.
    #@{(theronleads) He stops moving his fingers altogether|I stop moving my fingers altogether}.
        "Maybe I've been too generous."

        @{(theronleads) He presses the heel of his hand to your entrance, but that's as much as he gives you. You have to keep from twisting in his grip, from digging your nails into his forearms, from begging him for even the tiniest bit of friction. He doesn't give it to you. Not there, anyway. His mouth charts the shape of your shoulder, his thumb circles your nipple. Then, finally, mercifully, he slips his fingers inside you|Your free hand skates up his torso, your lips chart the shape of his shoulder. He grips the edge of the bed, the torment in his face unlike any you've seen in his nightmares. Then you begin pumping him again, and he bites his lip as though to keep from crying out}.

@{(theronleads) You can't help but cry out, watching your reflection come undone as he slides in and out of you|So this is what it takes for him to come undone, you can't help but think}.

@{(theronleads) "Theron," you repeat|"Goddess," he repeats}. A warning this time.

One @{(theronleads) he heeds, letting go off you long enough for you to|you heed. But you're not done. He realizes as much when you} glide off the bed and stand by the mirror. For a moment, he doesn't move. He merely stares at the slight curve of your back as you grip the pretty frame. Offering yourself up like a willing sacrifice. 

Then he's behind you.

*label sextheron
*page_break

*if virgin
    Hesitation flashes across your face. You haven't done this before. Not this part, anyway.

    Theron pauses.
    
    "${name}?" He sounds concerned. "We can stop. We don't have to…"

    *choice
        #Stopping is the last thing I want to do.
            *set virgin false
            *set theronoutcome 5
                
            You shake your head. "I don't want to stop."
    
            "You're certain?"

            You nod. He holds your gaze in the mirror as he slowly, gently eases into you. 
            
            There's the tiniest suggestion of pain, but it's nothing a goddess can't handle. 
            
            Especially one that is already aching. For him, for this.
            *goto sextheron1            
        #I nod and straighten. I want to stop.
            *set theronoutcome 6
            You turn around to face him. 

            "I'm not ready for this yet." You feel yourself blush, suddenly aware of how exposed you are. "Is that okay?"

            He blinks away the desire darkening his gaze and takes your hands in his. "Of course it's okay."
            *goto postkiss1
*else
    *set theronoutcome 5
    He sinks into you gently, meeting your gaze in the reflection.
    *goto sextheron1

*label sextheron1
*page_break Fates Yes

Part of you wants to close your eyes, let yourself be swept away by the pleasure building inside you like a wave. 

But you don't. 

You keep them open and on the mirror. 

On the sweat glistening on his chest, the moonlight glinting off yours. 

On his fingers, roving between your thighs so he can touch you as he thrusts into you.

You both know where his fate leads, one way or another. But all that knowledge does is add more urgency to his movements. 

To the moans that tear from your throat when you come and the grunts that escape from his when he does, holding onto you as though he's at sea and you're the only thing keeping him afloat.

You let go of the mirror and relax onto his chest. He's out of breath and his heartbeat leaps between your shoulder blades.

Later, you listen to it as you lie in his bed, cheek pressed to his chest.

*label theronsleep
*page_break

@{(virgin) You lie in his bed, cheek pressed to his chest|His skin is no longer slick with sweat–he brought over a pitcher of water and a cloth so that you could clean up–but the memory of it lingers in the air}.

His fingers trace circles on your back. They grow slower the closer he gets to sleep.

The closer he gets to nightmares.

Medea may be right. Fate isn't a noose. 

But a thread can still cut, if it's tied tight enough.
*goto main41

*label rejectedtheron

*if dontwanttheron
    He must sense it, for hurt flickers in his eyes.

    But it only lasts a second before he puts the charming Lord mask back. 
                
    "My apologies, goddess. I did not mean to overstep," he says in that smooth way of his. "I better get some rest, then. Before…."

    Before you do Hermes's bidding.
    *goto rejectedtheron2
*else
    *goto rejectedtheron2

*label rejectedtheron2

@{(justfriendstheron) You give him a small smile|You nod curtly}. "Good night."

Neither of you voice the obvious. That for him, it won't be a good night for long.

Medea may be right. Fate isn't a noose.

But a thread can still cut, if it's tied tight enough.
*goto main41

*label postkiss

It takes all your self-control to peel yourself away from him.

He blinks at you, eyes dark with desire.

"I can't," you whisper, 
*if theronoutcome = 3
    resisting the urge to cup his cheek.
    *goto postkiss1
*else
    cupping his cheek.
    *goto postkiss1

*label postkiss1

He doesn't question you, doesn't try to change your mind. He just nods and presses his lips to your palm, softly, wistfully, 
*if (theronoutcome = 5) and (pcnaked = true)
    then grabs your @{(style) chitoniskos|chiton|peplos} from the ground and helps you back into it.
    *goto postkiss2
*elseif (theronoutcome = 5) and (pcnaked = false)
    then adjusts your @{(style) chitoniskos|chiton|peplos} so that you're covered up.
    *goto postkiss2
*else
    then takes a step back.

    "I better get some rest, then. Before…."

    Before you do Hermes's bidding.

    When he's gone, you bring your fingers to your lips.

    Medea may be right. Fate isn't a noose.

    But a thread can still cut, if it's tied tight enough.
    *goto main41

*label postkiss2
*page_break

"I better get some rest, then," he says. "Will you lie with me? Until …."

Until you must do Hermes's bidding.

"Of course."
*goto theronsleep

*label main41
*page_break After Dawn

@{(theronoutcome) Fate is still on your mind|Fate is still on your mind|Thoughts of Theron continue to torment you|You can still taste Theron on your lips|The scent of Theron clings to your skin|You can still taste Theron on your lips} as you near the southern cliffs.

By the time you finished weaving Theron's nightmare and left the dream realm behind, dawn was hot on your heels.

It lights the way to the cave, making the sea glitter in its wake. But the wind is strong this morning, and it takes you longer than usual to reach its mouth.

And to hear Morpheus and Hermes arguing within.

*page_break

"Do you think me a fool, Morpheus?" 

They're out of your line of sight, but Hermes hurls the words at Morpheus with enough venom to slice through the wind's onslaught.

"Do you want me to answer that honestly?" Morpheus hurls back.

Then the wind picks up, swallowing the rest.

What do you do?

*choice
    #I climb the wall inside the cave and find a good spot to eavesdrop.
        *set onledge true
        @{(flightstyle) The flap of wings might alert them of your presence, so you tuck them in tight and|You use your shadows to bolster you as you|The rustle of feathers might alert them of your presence, so you keep the wings of your sandals flush with your ankles and} grab onto an outcrop of rock.

        *if fitness > 60
            *set hermesargument 1
            *set maverickgoddess %+10
            *set olympusinfluence %+10
            Then you're scaling the craggy wall with an ease even the most seasoned of athletes would envy.

            It doesn't take you long to reach a ledge overlooking the heart of the cave. You hoist yourself onto it and find a good vantage point to watch the scene unfolding below.

            There, next to the gleaming gate, Morpheus is squaring up to Hermes as though he isn't one of the most powerful gods in Olympus, let alone his boss. 
            *goto listened
        *else
            *set hermesargument 2
            *set olympusinfluence %-10
            *set underworldinfluence %-5
            *set respect %-20
            *set morpheusrift true
            But scaling the craggy wall is more challenging than you thought, @{(flightstyle) especially without the use of your wings|and you can't seem to co-ordinate your movements with your shadows'|and your feet are clumsy without winged sandals to aid them}.

            You catch a glimpse of Morpheus squaring up to Hermes by the gleaming gate. As though the herald isn't one of the most powerful gods in Olympus, let alone his boss.

            You eye a ledge that will give you a good vantage point not too far away and begin struggling towards it. Every inch you gain is a challenge.
            
            So much for divine strength.

            And, you realize after you miscalculate the distance between your foot and a crack in the rock, divine wit. 
            
            Cursing yourself, you plummet, desperately @{(flightstyle) flapping your wings|gathering your shadows|kicking the air} in an attempt to break the fall.

            It doesn't work. You hit the ground hard, sending up a cloud of rubble and dust.

            When it clears, Hermes and Morpheus are bent over you, sporting matching glares.
            *goto gotcaught
    #I blend into the shadows and sneak close enough to eavesdrop.
        You slip into the cave, @{(flightstyle) tucking your wings in tight, careful not to brush them against the rock|using your own shadows as cover|light on your feet, and keeping your wings flush to your ankles}.

        *if stealth > 60
            *set hermesargument 1
            *set maverickgoddess %+10
            *set underworldinfluence %+10
            Melting into the dark feels as natural as flying, and you inch toward the heart of the cave without making a sound.

            Next to the gleaming gate, Morpheus is squaring up to Hermes as though he isn't one of the most powerful gods in Olympus, let alone his boss. 

            They don't notice you approach, don't so much as glance at the corner where you perch, and become one with the shadows.
            *goto listened
        *else
            *set hermesargument 2
            *set respect %-20
            *set olympusinfluence %-5
            *set underworldinfluence %-10
            *set morpheusrift true
            You inch towards the gate, where Morpheus is squaring up to Hermes as though he isn't one of the most powerful gods in Olympus, let alone his boss.
            
            But your efforts not to make a sound are in vain.

            Morpheus's head snaps up as soon as you approach, as though he can sense you lurking in the dark. The suddenness of the movement catches you off guard, and your foot gets caught in a crack in the rock.

            A surprised yelp tears from your throat, drawing Hermes's attention–and his wrath.

            He wheels around, pinning his glare on you.
            *goto gotcaught
    #I make my presence known. Whatever this is, I better put a stop to it.
        *set queenly true
        You march into the cave, determined to take control of the situation before it escalates.

        *if leadership > 50
            *set hermesargument 1           
            *set olympusinfluence %+5
            *set underworldinfluence %+5
            *set pantheonplayer %+10
            *set respect %+20
            And it's a good thing, too, because next to the gleaming gate, Morpheus is squaring up to Hermes as though he isn't one of the most powerful gods in Olympus, let alone his boss. 
            *goto listened
        *else
            *set hermesargument 2
            *set respect %-10
            *set Morpheus %-5
            *set pantheonplayer %-15
            You realize your mistake as soon as you reach the pool of light drifting from the gate. 

            Morpheus is squaring up to Hermes as though he isn't one of the most powerful gods in Olympus, let alone his boss. And Hermes…Hermes is madder than you've ever seen him.
            *goto listened
    #I make my presence known. This conversation isn’t meant for my ears.
        You flit towards the heart of the cave, clearing your throat and @{(flightstyle) flapping your wings as loudly as you can so they can hear you coming|stretching your shadows so that they can hear and see you coming|stomping your feet so that they can hear you coming}.

        *if dutiful > 50
            *set hermesargument 3
            *set respect %+10
            *set pantheonplayer %+5
            *set olympusinfluence %+5
            "Hermes? Morpheus?" You call out as you near the gate.

            You reach it in time to catch Hermes stepping away from Morpheus, whose glare is coated in cold defiance. The herald is gripping his staff as though he'd very much like to bash the god of dreams over the head with it, and rage distorts his pretty features.
            
            It dissipates as soon as he faces you.

            "${name}. What a lovely surprise."

            Morpheus smirks.

            "Is it? With [i]so many[/i] mortals to torment, it's a miracle she's back before sunset."

            *fake_choice
                #I balk at Morpheus. He shouldn't defy Hermes.
                    *set Morpheus %-10
                    *set respect %+10
                    *set morpheusrift true
                    "Behave," you hiss at Morpheus. 

                    Hurt flashes across his face. Then it's gone, swallowed up by anger.
                #I blink at Morpheus. Is he really speaking up for me?
                    *set Morpheus %+5
                    He merely shrugs, but his gaze softens a little. 

                    That's new. @{(Morpheus < 50) You don't know how to feel about it.|You…like it?}
                #I glower at Morpheus. I don't need him to speak for me.
                    *set charm %-5
                    *set respect %+5
                    *set morpheusrift true
                    He waves you off. "Please don't mistake my words for concern. I am merely using you to make a point."

                    It's your turn to smirk.

                    "If your point is that you're a lazy cheat who is ill-prepared for his position, don't bother. We're well aware."

                    His mouth twists into a sneer.
            
            @{(morpheusrift) Hermes nods at you approvingly|Hermes rolls his eyes}.

            @{(morpheusrift) "You could stand to learn a thing or two from your fellow Messenger, son of Hypnos. Following simple instructions, for one. A little common decency, for another,"|"While your concern for your fellow Messenger is touching, son of Hypnos, it seems rather misplaced, for [i]she[/i] isn't the one unable to follow simple instructions. I would be far more concerned about yourself, if I were you,"} he says, twirling his staff.

            Morpheus stiffens. But Hermes is already moving, wings flapping against the dark. 
            
            "Alas, time is of the essence, and mine is always short. We shall table this matter for now, yes?" He doesn't wait for Morpheus to respond, turning to you instead. "${name}, pleasure to run into you." 
            
            He doesn't bother bidding Morpheus farewell before he flits towards the mouth of the cave.
            *goto hermesleaves
        *else
            *set hermesargument 2
            *set respect %-5
            *set pantheonplayer %-10
            But they're too wrapped up in their argument to notice you, even after you reach the gate, where Morpheus is squaring up to Hermes as though he isn't one of the most powerful gods in Olympus, let alone his boss.
            *goto listened

*label listened
*page_break

"This better be the last time you go against one of my commands," Hermes warns, gripping his staff.  

The herald looks nothing like the hopelessly aloof–and perpetually bored–god you're used to. Perhaps it's the fact he's neither fidgeting nor hovering nor hurrying. Or perhaps it's the edge in his voice, so sharp you can feel it 
*if (hermesargument = 1) and (queenly = false)
    @{(onledge) all the way up here|even in the little dark corner you've claimed as your vantage point}.

    "[i]Your[/i] commands? I thought they were Zeus's."

    For a moment, you think Hermes might actually club Morpheus over the head with his staff. As much as you can relate to the impulse, dread shoots up your spine.

    "To you, they are one and the same," the herald snarls.

    Morpheus lifts his chin, all cold defiance.  

    "For now."

    His words make the rage in Hermes's delicate features flare.

    *fake_choice
        #Fear slices through me. What if he hurts Morpheus?
            *set Morpheus %+5
            It's immediately followed by confusion. Since when do you care what happens to Morpheus?
        #My curiosity flares. Why is he so furious?
            *set cunning %+5
            Sure, Morpheus is aggravating in the extreme. But Hermes's wrath is far too great to be the result of Morpheus's usual petty tricks.
        #I'm angry on his behalf. What has Morpheus done now?
            *set Morpheus %-5
            Something awful, no doubt. And big. Hermes's wrath is far too great to be the result of Morpheus's usual petty tricks.
    
    @{(onledge) Gripping the ledge, you lean in closer|You retreat further into the shadows} and listen carefully.

    "You had better harden your heart, son of Hypnos. Mortals may thank you for over-delivering on sweet dreams, but I promise the extra worship won't be worth the punishment."

    The threat isn't aimed at you, but it sends a shiver down your spine all the same.

    "Not everything is about worship," Morpheus says.

    Hermes's lips twitch into a sinister grin. "Ah, but you see, that's where you're wrong. Worship [i]is[/i] everything."

    With that, he shoves past Morpheus, flying out of the cave and into the wind beyond.
    *goto hermesleaves
*else
    chafe against your skin as you approach.

    *if hermesargument = 1
        But it doesn't deter you one bit.

        "[i]Your[/i] commands? I thought they were Zeus's," Morpheus snarls.

        For a moment, you think Hermes might actually club Morpheus over the head with his staff.

        "That's enough."

        Your voice cuts through the tension in the air, chasing some of the hostility from their faces–and making them stand a little straighter.
        *goto diffused
    *else
        *set ashamed true
        *set morpheusrift true
        @{(queenly) You clear your throat, determined to steer them away from mutual destruction. But, when Hermes wheels around to face you, your confidence evaporates|Only when you're standing right in front of them do they finally notice you}.
        *goto gotcaught

*label diffused 
*page_break

"Whatever is going on here, I am certain there is a much better way to handle it than thinly veiled threats and petty remarks."

Morpheus narrows his eyes at you. But the stubborn defiance you glimpsed before is already fading from his expression, replaced by his usual brand of haughtiness.

"You're right," Hermes sighs.

He flicks Morpheus a tight-lipped smile.

"Forgive me, it has been rather hectic lately. Still, I shouldn't have reacted like that. Especially not over a simple misunderstanding."

Morpheus opens his mouth, no doubt to argue anew, but Hermes cuts him off before he gets the chance. "Why else would you have over delivered on sweet dreams, if not because you misread my instructions?"

*fake_choice
    #I shoot Morpheus a pointed look. Defying Hermes like this is wrong.
        *set Morpheus %-5
        *set respect %+10
        *set morpheusrift true
        The glare he shoots you in return is cold enough to send ice down your spine. 

        But he nods at Hermes, whose grin widens.
    #I raise my eyebrows at Morpheus. Defying Hermes like this is short-sighted.
        *set cunning %+5
        *set Morpheus %+5
        Not only does it put him at risk, but it also risks the position of the Underworld.

        Understanding flashes across Morpheus's face. He nods, then bares his teeth at Hermes. Not quite a smile, but close enough.

        "No other reason."
    #I stare Hermes down. I thought we were past this.
        *set respect %-5
        *set charm %-5
        The herald's grin tightens. 

"Well, having cleared that up, I'm afraid I must love you and leave you."

He bows his head at you and waves at Morpheus. Then he's flying towards the mouth of the cave and into the wind beyond.
*goto hermesleaves

*label gotcaught
*page_break

"Eavesdropping, are we?" the herald snarls.

@{(ashamed) "I wasn't," you begin, but he lifts a hand and the words die on your lips|You merely sigh. Hard to deny it when they caught you in the act}.

"I've had enough of the pair of you. You," Hermes points a finger at Morpheus. "Consider yourself warned."

He then aims the same finger at you. "And you. Stay out of my way."

@{(onledge) It feels beyond embarrassing to get a talking to while sprawled on the ground like this, so you scramble to your feet. Neither of them offers you a hand|Shame bites your cheeks}.

Hermes shoves past you, flying out of the cave and into the wind before you can so much as blink.

*label hermesleaves
*page_break

*if (hermesargument = 1) and (queenly = false)
    For a moment, Morpheus watches the mouth of the cave, as though expecting Hermes to return and make good on his threat.

    When he doesn't, he sighs, and the sound is so full of relief, so out of character for the god of dreams, it almost surprises a laugh out of you. You manage to stifle it, watching concern replace his snarl.

    It's strange to see him like this. So upset, so…vulnerable.

    *fake_choice 
        #I look away out of respect.
            *set dutiful %+5
            Granting him some privacy is the least you can do.

            You hear the cries of the damned waver when he crosses the gate.
        #I look away out of kindness.
            *set ruthless %-5
            *set Morpheus %+5
            Yes, you eavesdropped. But that doesn't mean you're [i]completely[/i] devoid of decency.

            You hear the cries of the damned waver when he crosses the gate.
        #I can't make myself look away.
            *set Morpheus %+5
            He rubs his eyes and rakes his fingers through his hair.

            Slowly, his fear recedes and he gathers enough composure to stalk through the gate.

    But you remain where you are, even if it means he'll win tonight's race.

    What you've gained is far more valuable than that.
    
    *choice
        #Continue to the next chapter.
            *finish Chapter 7
        *if (not(choice_randomtest)) #Restore to the previous checkpoint.
            *restore_checkpoint
*else
    "Nice work," Morpheus @{(morpheusrift) snaps|admits}.

    @{(morpheusrift) You roll your eyes|You nod}.
    
    He's trying to hide it, but you can tell he's shaken by the exchange. His eyes keep bouncing around the cave, and his wings won't stop twitching.

    *if (queenly = true) and (morpheusrift = false)
        "You should be careful out there, ${name}," he says, voice soft.

        Then he turns his back on you. 

        It isn't until he's gone that you realize he didn't call you Princess.
            
        *choice
            #Continue to the next chapter.
                *finish Chapter 7
            *if (not(choice_randomtest)) #Restore to the previous checkpoint.
                *restore_checkpoint
    *else
        "Be careful out there, Princess," he says. His voice isn't quite soft, but it isn't as venomous as usual.

        Then he turns his back on you and stalks through the gate, leaving you alone with your racing thoughts.
        
        *choice
            #Continue to the next chapter.
                *finish Chapter 7
            *if (not(choice_randomtest)) #Restore to the previous checkpoint.
                *restore_checkpoint